Cancel
Showing results for 
Search instead for 
Did you mean: 

NX

Pioneer
Pioneer

Dear Sir,

I want to restore NX to it's default position. How I can do it?

should i remove log files if yes then how?

 

 

 

Thanks,

APS

3 REPLIES

Re: NX

Gears Esteemed Contributor Gears Esteemed Contributor
Gears Esteemed Contributor

RE: default position

Location varies a bit by version, but try:

Preferences -> User interface -> (not sure which tab) -> Reset window position

 

Ken Akerboom Sr CAx Systems Engr, Moog, Inc.
Production: NX10.0.3.5 MP16/TC11.2
I'd rather be e-steamed than e-diseaseled


Re: NX

Gears Esteemed Contributor Gears Esteemed Contributor
Gears Esteemed Contributor

Re: Log files

yes, they should be cleaned up occasionally (as should the TMP/TEMP folders in general).

I have seen very strange problems in NX that went away once the temp folders (that had 2000+ files in them) were cleaned up.

 

I have a bat file that runs automatically when I log in.

Or you could do it just before log off.

just DO NOT do it while any applications are running

Ken Akerboom Sr CAx Systems Engr, Moog, Inc.
Production: NX10.0.3.5 MP16/TC11.2
I'd rather be e-steamed than e-diseaseled


Re: NX

Legend
Legend

I'm not sure who authored this, I found it many years ago here or on eng-tips. I run it manually once a week or so. More often if NX starts to seem slow. Though since we went to SSD drives, I dont notice it as much.

 

rem ### logoff script to clear temporary folder,
rem ### but keep NX syslogs for a specified number of days
rem
rem ### save as ClearTempFolder.cmd

set SysLogKeepDays=1

rem ### get rid of ugs_router syslogs

for %%F in ( %TMP%\ugs_router* ) do del /f /q "%%~F"

rem ### delete temporary files and folders

attrib -r -s -h "%TMP%\*" /s /d

for /d %%D in ( %TMP%\* ) do rmdir /s /q "%%~D"

if "%DATE:~2,1%" EQU "/" (
    call :ParseEnglishDate %DATE%
) else (
    call :ParseDate %DATE%
)

call :DateToDays
set /a LimitDays="%DateDays% - %SysLogKeepDays%"

for %%F in ( %TMP%\* ) do call :CheckFile "%%~F" "%%~tF" "%%~xF"

rem ### prevent falling into subroutines

goto :EOF

rem ### subroutines

:CheckFile
    if "%~3" NEQ ".syslog" goto :DeleteMe
    
    if "%DATE:~2,1%" EQU "/" (
        call :ParseEnglishDate %~2
    ) else (
        call :ParseDate %~2
    )

    call :DateToDays
    if %DateDays% GTR %LimitDays% goto :EOF

:DeleteMe
    del /f /q "%~1"
goto :EOF

:ParseDate
    for /F "tokens=1,2,3 delims=." %%A in ('echo %~1') do (
        set /a Day="1%%~A - 100"
        set /a Month="1%%~B - 100"
        set Year=%%~C
    )
goto :EOF

:ParseEnglishDate
    for /F "tokens=1,2,3 delims=/" %%A in ('echo %~1') do (
        set /a Day="1%%~B - 100"
        set /a Month="1%%~A - 100"
        set Year=%%~C
    )
goto :EOF

:DateToDays
    set /a YearDays="%Year% * 365"
    set /a MonthDays="%Month% * 30"
    set /a DateDays="%YearDays% + %MonthDays% + %Day%"
goto :EOF

 

 

Rob Newcomb, CAD/CNC/Simulation manager
Elmhirst Industries, Specializing in Prototype sheet metal stampings and assemblies

Production: NX 12.0.2 / Autoform r7 /WorkNC 2018 r2
Testing:NX EAP
PC: Rave Cadbeast: Intel(R) i7-4790K CPU @ 4.GHz /32gb ram /NVIDIA Quadro P2000 on Win10 Pro